home *** CD-ROM | disk | FTP | other *** search
/ CDUTIL 13 / CDUTIL #13 Julio 1995.iso / windows / acadwin / support / dde.lsp < prev    next >
Encoding:
Lisp/Scheme  |  1995-02-08  |  15.7 KB  |  393 lines
  1. ;                             DDE.LSP
  2. ;
  3. ;  ________________________________________________________________________
  4. ;  
  5. ;  (C) Copyright 1990-1993 by Autodesk, Inc.
  6. ;    by Phil Ford
  7. ;
  8. ;  Permission to use, copy, modify, and distribute this software and its
  9. ;  documentation for any purpose and without fee is hereby granted.  
  10. ;
  11. ;  THIS SOFTWARE IS PROVIDED "AS IS" WITHOUT EXPRESS OR IMPLIED WARRANTY. 
  12. ;  ALL IMPLIED WARRANTIES OF FITNESS FOR ANY PARTICULAR PURPOSE AND OF 
  13. ;  MERCHANTABILITY ARE HEREBY DISCLAIMED.                                
  14. ;  ________________________________________________________________________
  15. ;
  16. ; 
  17. ;  DDE.LSP data between AutoCAD and a concurrently running spreadsheet
  18. ;  program using the Dynamic Data Exchange feature of Windows.
  19. ;  This program relies on the ADS program, DDELISP.EXE, to call Windows.
  20. ;
  21. ;
  22. ;---------------------------
  23. ;
  24.  
  25. ;  Main AutoLISP commands:
  26. ;       c:send - send tables and drawing to DDE app
  27. ;       c:get - read data back in and modify any changed entities
  28. ;       sendset - send a selection set
  29. ;
  30. ;  Main DDE functions (implemented with ADS functions in DdeLisp.exe):
  31. ;       ddeprompt - Open channel to default app, put up dialog if failure.
  32. ;                   The DDE dialog saves values in windows\ddelisp.ini.
  33. ;       setddeformat -  AutoCAD Entity filters and layout
  34. ;           0 = all data, use entity names
  35. ;           1 = all data, use handles and not names
  36. ;           2 = decimal handle, handle, tag1, attr1; dec handle, 
  37. ;                               handle, tag2, attr2; ...
  38. ;                       each block insert on one row 
  39. ;           3 = same as 2 but without tags
  40. ;       senddrawing - sends tables, 5 blank lines, rest of drawing
  41. ;       moddrawing - imports data from DDE program and modifies
  42. ;               any drawing entities that have changed
  43. ;       pokealltbl - sends drawing table data to remote app
  44. ;       pokeall - sends drawing entities
  45. ;       pokeset - sends selection set
  46. ;       advise - set up warm link on last item sent
  47. ;       reqmod - requests data and modifies drawing entities
  48. ;               with the data, using a specified range (speed opt)
  49. ;       ddefree  - call after the DDE request data function
  50. ;               "request", to free the shared data transferred from 
  51. ;               a remote application.
  52. ;       ddedone - terminate all DDE channels and free memory
  53.  
  54. ;  Main global variables:
  55. ;       chnl - DDE channel number  (32 allowed)
  56. ;       topic - work file (spreadsheet name)
  57. ;       item - DDE item (cell range description)
  58. ;       row1, col1 - start of spreadsheet data
  59. ;       rowcnt - sum of rows used by last drawing
  60. ;               transmission
  61.  
  62.  
  63.  
  64. ;       Send all the tables and entities to the remote
  65. ;       DDE program (app) on the channel created by ddestart
  66. ;       using "senddrawing" function
  67. (defun c:send ()
  68.   (chkdde)                              ;Check open chnl, prompt user if not
  69.   (unadvise chnl "")                    ;Clear hot link on last item sent
  70.   (sendheading)
  71.   (princ "\nSending drawing data...\n")
  72.   (setq rowcnt (senddrawing row1))
  73.   (advise chnl "" linkcommand)          ;Set up warm link on last 
  74.                                         ;  item sent ("").  When new data comes
  75.                                         ;  in, interrupt AutoCAD and request
  76.                                         ;  the moddrawing function
  77.   (princ "\nNumber of rows used by drawing: ")
  78.   (princ rowcnt)
  79.   (princ "\n")
  80.   (princ)
  81. )
  82.  
  83.  
  84.  
  85. ;       Request data and modify drawing
  86. (defun c:get ()
  87.   (chkdde)                              ;Check open chnl, prompt user if not
  88.   (setq en (entnext))                   ;get first entity name
  89.   (princ "Receiving data and modifying drawing...\n")
  90.   (if (= rowcnt 0)(setq rowcnt 18000))  ;to read in spreadsheet data when
  91.                                         ;  we wrote it in a previous
  92.                                         ;  session, we don't
  93.                                         ;  know the number of rows.  Just
  94.                                         ;  set high limit on read, so  
  95.                                         ;  "moddrawing" will continue until 
  96.                                         ;  end of spreadsheet data.
  97.   (setq modcnt (moddrawing row1 rowcnt))
  98. )
  99.  
  100.  
  101. ;       Send all the tables and then the entities to the remote
  102. ;       DDE program (app) on the channel created by ddestart,
  103. ;       using "pokealltbl" and "pokeall"
  104. (defun sendall ()
  105.   (chkdde)                              ;Check open chnl, prompt user if not
  106.   ;Send all the tables
  107.   (setq tabrows (lenalltbl))            ;in case you need the length before
  108.                                         ;  you send them
  109.   (setq row row1)
  110.   (setq tblrows (pokealltbl chnl row col1)) ;send all the tables
  111.   (setq row (+ row tblrows))            ;set row to end of drawing data in
  112.                                         ;  the spreadsheet
  113.   (setq row (+ row 5))                  ;leave blank lines
  114.   (princ "Rows used by the tables: ")
  115.   (princ tblrows)
  116.   (princ "\n")
  117.  
  118.                                 ;TABLE Definitions
  119.                                 ;VPORT 0
  120.                                 ;LTYPE 1
  121.                                 ;LAYER 2
  122.                                 ;STYLE 3
  123.                                 ;VIEW  4
  124.                                 ;UCS   5
  125.                                 ;BLOCK 6
  126.                                 ;DIMSTYLE 7
  127.  
  128.   (setq blkrows (lentbl 6))     ;6=BLOCK
  129.   (princ "\nNumber of rows in blocks: ")
  130.   (princ blkrows)
  131.   (princ "\n")
  132.  
  133.                         ;Send a table individually--this is just a
  134.                         ;  test.  We already sent all the tables,
  135.                         ;  including the BLOCK table.
  136. ; (setq item (cellstr row col1 rowcnt 4))  ;from row, col, rows sent
  137. ;                                       ;  previously  (4 cols)
  138. ;  (setq rowcnt (poketbl chnl item 6))  ;send BLOCK table (6)
  139. ;                                       ;  to spreadsheet with DDE
  140. ;  (setq row (+ row rowcnt))
  141. ;  (setq row (+ row 1))
  142. ;  (princ "Rows used by the blocks: ")
  143. ;  (princ rowcnt)
  144. ;  (princ "\n")
  145.  
  146.  
  147.   (princ "\nSending drawing data...\n")
  148.   (setq en (entnext))                   ;get first entity name
  149.   (setq rowcnt (pokeall chnl en row col1)) ;send whole drawing to remote
  150.                                         ;  spreadsheet with DDE
  151.   (princ "\nNumber of rows used by entities: ")
  152.   (princ rowcnt)
  153.   (princ "\n")
  154.  
  155.   (princ)
  156. )
  157.  
  158.  
  159. ;       Send a selection set to a remote application, using
  160. ;       "pokeset"
  161. (defun sendset ()
  162.   (chkdde)                              ;Check open chnl, prompt user if not
  163.   (sendheading)
  164.   (setq frmt (getddeformat))
  165.   (if (< frmt 2)
  166.     (setq sset (ssget))                 ;get a selection set of all codes
  167.     (setq sset (ssget "X" (list (cons 0 "ATTRIB"))))
  168.                                         ;just attributes
  169.   )
  170.   (unadvise chnl "")                    ;Clear hot link on last item sent
  171.   (setq rowcnt (pokeset chnl sset row1 col1)) ;send set to remote
  172.                                         ;  spreadsheet with DDE
  173.   (advise chnl "" linkcommand)          ;Set up warm link on last 
  174.                                         ;  item sent ("").  When new data comes
  175.                                         ;  in, interrupt AutoCAD and request
  176.                                         ;  the moddrawing function
  177.   (setq sset nil)
  178.   (princ "Rows: ")
  179.   (princ rowcnt)
  180.   (princ)
  181. )
  182.  
  183.  
  184.  
  185.  
  186. ;       Read DDE data (from DDE remote app)
  187. ;       starting at a certain row, and modify any entities
  188. ;       that have changed.  Allows
  189. ;       column 1 values of less than -4 for comments in
  190. ;       spreadsheet.  -1 is normal entity group code in column 1.
  191. ;       Demonstrates "reqmod" function.
  192. (defun mod ()
  193.   (chkdde)                              ;Check open chnl, prompt user if not
  194.   (setq mrow1 (getint "\nStart row: "))
  195.   (setq nrows (getint "\nNumber of rows: "))
  196.   (setq item (cellstr mrow1 col1 nrows 4))      ;from row, col, rows sent
  197.                                         ;  previously  (4 cols)
  198.   (setq mrowcnt (reqmod chnl item))     ;request range of data, modify
  199.                                         ;  entities that have changed
  200.   (setq entcnt (modcount))
  201.   (ddefree chnl)                        ;free shared data from remote app
  202.   (princ "\nEntities modified: ")
  203.   (princ entcnt)
  204.   (princ "\n")
  205.   (princ "Rows: ")
  206.   (princ mrowcnt)
  207.   (princ)
  208. )
  209.  
  210.  
  211. ;       
  212. ;       
  213. ;               Slower versions, transfer entities one at a time
  214. ;       
  215. ;       
  216.  
  217. ;       Send all the entities in the drawing to the remote app
  218. ;       one at a time.  Demonstates DDE functions
  219. ;       "poke", "request", "execute", and entity transfer function
  220. ;       "entpokecell"
  221. (defun sendall2 ()                      ;Dynamic Data Exchange Sample
  222.                                         ;  Usage
  223.   (chkdde)                              ;Check open chnl, prompt user if not
  224.   (setq cell (cellstr 1 1 1 1))         ;cell item "R1C1", row 1 col 1,
  225.                                         ;  1 number of rows, 1 ncols
  226.  
  227.                 ;Test DDE functions; poke, request, and execute
  228.   (poke chnl cell  
  229.     "AutoCAD / Excel Demo .25...............40.................60.................80") 
  230.                                         ;poke-send data for the cell, check
  231.                                         ;  string length abilities of system
  232.   (setq data (request chnl cell))       ;request-get data from a cell
  233.   (ddefree chnl)                        ;free request data (shared data from
  234.                                         ;  remote app)
  235.   (princ "Data from Spreadsheet: \n")
  236.   (princ data)
  237.   (princ "\n")
  238.   (setq cell (cellstr 1 3 1 1))         ;cell item "R1C1", row 1 col 3
  239.   (setq execstr "[SELECT(\"R1C1\")][FORMULA(\"AutoCAD Graphics Data\")]")
  240.   (execute chnl execstr)
  241.  
  242.  
  243.                         ;Send entities one by one
  244.   (setq en (entnext))                   ;get first entity name
  245.   (setq row row1 col col1)              ;start spread sheet in row 2, col 1
  246.   (setq rowcnt 0)
  247.   (while (not (null en))
  248.     (setq rows (entpokecell chnl en row col))
  249.     (setq rowcnt (+ rowcnt rows))
  250.                                         ;fill cells with entity data list.
  251.                                         ;  rows is the number of items
  252.                                         ;  in list
  253.     (setq row (+ row rows))             ;move down to bottom of that entity
  254.                                         ;  in spreadsheet
  255.     (setq en (entnext en))              ;get next entity name
  256.     (princ "\nNext Available Row ")
  257.     (princ row)
  258.     (princ)
  259.   )
  260.                                         ;just a test--not necessary:
  261.   (setq cell (cellstr row 1 1 1))       ;  create cell string, such as
  262.                                         ;  "R1C1:R2C2", row col nrows ncols
  263.   (poke chnl cell "-99")                ;comment to flag end of sheet
  264.   (princ)
  265. )
  266.  
  267.  
  268. ;       Send a selection set to remote app, one by one.
  269. ;       Demonstates use of entpokecell.
  270. (defun sendset2 ()
  271.   (chkdde)                              ;Check open chnl, prompt user if not
  272.   (setq sset (ssget))                   ;get a selection set
  273.   (setq idx 0)
  274.   (setq en (ssname sset idx))           ;set en to first entity
  275.   (setq row row1 col col1)              ;starting spreadsheet cell
  276.   (setq rowcnt 0)
  277.   (while (not (null en))
  278.     (setq rows (entpokecell chnl en row col))   ;fill cells with entity data
  279.                                         ;  list. rows is the number of items
  280.                                         ;  in list
  281.     (setq row (+ row rows))             ;move down to bottom of that entity
  282.                                         ;  in spreadsheet
  283.     (setq rowcnt (+ rowcnt rows))       
  284.     (setq idx (+ idx 1))
  285.     (setq en (ssname sset idx))         ;set en to idx'th entity
  286.     (princ "\nRow ")
  287.     (princ row)
  288.     (princ)
  289.   )
  290.   (setq sset nil)
  291. )
  292.  
  293.  
  294. ;       Input data from remote app on all the entities in the drawing,
  295. ;       and update any that have changed, with entmod.  Entities
  296. ;       are transferred in sections 100 rows each.
  297. ;       Demonstrates DDE function "reqmod".
  298. (defun mod2 ()                          ;Dynamic Data Exchange Sample
  299.                                         ;  Usage
  300.   (chkdde)                              ;Check open chnl, prompt user if not
  301.   (setq row row1 rows 0 modtot 0)       ;start at top of spreadsheet
  302.   (setq rowtot 0)
  303.   (while (< rowtot rowcnt)              ;while there are more rows to check
  304.                                         ;  based on how many were sent
  305.     (setq item (cellstr row col1 100 4)) ;read in 100 rows at a time
  306.     (princ item)
  307.     (princ " ")
  308.     (setq rows (reqmod chnl item))      ;get data from spreadsheet, and
  309.                                         ;  convert to entities
  310.     (princ rows)
  311.     (princ " ")
  312.     (setq modcnt (modcount))            ;(modcount) gets the last
  313.                                         ;  count value
  314.     (setq modtot (+ modtot modcnt))     ;update modified count.
  315.     (setq row (+ row rows))             ;move down to bottom of that entity
  316.                                         ;  in spreadsheet
  317.     (setq rowtot (+ rowtot rows))
  318.     (princ "Row: ")
  319.     (princ row)
  320.     (princ "\n")
  321.   )
  322.   (princ "\nEntities modified: ")
  323.   (princ modtot)
  324.   (princ)
  325. )
  326.  
  327.  
  328. ;       Make sure we have a DDE channel.  Create one if not.
  329. (defun chkdde ()
  330.   (setq chnl (getddechnl))              ;Ask ddelisp.exe if we have a DDE
  331.                                         ;  channel open
  332.   (if (= 0 chnl) (progn
  333.     (setq chnl (ddeprompt))             ;Try to load app, open channel.  If
  334.                                         ;  fail, put up dialog for app, 
  335.                                         ;  topic, and command line.
  336.     (if (= 0 chnl) (progn
  337.       (princ "No DDE conversation open\n")
  338. ;      (quit)
  339.       ) 
  340.       (setglobals) 
  341.       )
  342.     )
  343.   )
  344. )
  345.  
  346.  
  347. ;       Re-init AutoLISP globals for each new drawing.
  348. (defun setglobals ()
  349.   (setq row1 3 col1 1 rowcnt 0 ddeflag T)
  350.   (fprecision 4 0.01)                   ;Set transfer floating point
  351.                                         ;  precision and fuzz
  352.                                         ;  factor for compares
  353.   (setvar "cmdecho" 0)
  354.   ;(command "_handles" "_on")
  355.   (sethandles)                          ;ADS/DDE function that checks and
  356.                                         ;  sets handles on if they're off.
  357.   (setddeformat 1)                      ;Use handles, not ent names. 
  358.   (setq linkcommand "(moddrawing 3 20000) ")
  359.                                         ;When hot link data comes in, 
  360.                                         ;request row 3 through 20000
  361.                                         ;(or less if spreadsheet has less
  362.                                         ;rows)
  363.   (princ "DDE.LSP and DDELISP.EXE loaded\n")
  364.   (princ)
  365. )
  366.  
  367. ;       Send a title to the spreadsheet
  368. (defun sendheading ()
  369.   (setq cell (cellstr 1 2 1 1))         ;cell item row 1 col 2, 1 row, 1 col
  370.                 ;Test DDE functions; poke, request, and execute
  371.   (poke chnl cell "AutoCAD Drawing Data") 
  372. )
  373.  
  374. ;       To enable (quit) function, to emulate C "break" or "return"
  375. ;(defun *error*(msg)                    ;silent quit from function
  376. ;  (prin1)
  377. ;)
  378.  
  379. ;       Initialize when loading dde.lsp.
  380. (if (null initiate) (progn              ;DDELISP.EXE not loaded.
  381.   (xload "ddelisp")                     ;ADS program that contains the DDE
  382.                                         ;  AutoLISP functions.
  383.   )
  384. )
  385.  
  386. (setq chnl (getddechnl))                ;Ask ddelisp.exe if we have a DDE
  387.                                         ;  channel open
  388. (setq app (getddeapp) topic (getddetopic)) 
  389. (setglobals)
  390.  
  391.  
  392. ;<end of file>
  393.